Wikidata:WikiProject Antiquity/Pauly-Wissowa

[[|Administration]]

[[|Subjects]]

Ancient Rome

Ancient Greece

Pauly-Wissowa's Realencyclopädie

Introduction

Wikimedia Commons

Wikimedia Commons has media about Pauly-Wissowa in Wikimedia projects.

This page gives information on the RE project, an effort by the German Wikisource community to create a digital (wikified) version of (parts of) Paulys Realencylopädie der classischen Altertumswissenschaften. The aim of this page is to facilitate proper incorporation and curation of the data produced by the RE project on Wikidata.

The scope of the RE project on Wikisource, started in 2007 by the community, is limited to those parts of the work not protected by German copyright law, namely:

articles written by authors who have died more than 70 years ago (i.e. in 2026, all authors who died in or before the year 1955)
articles below the threshold of originality, which is defined by the project as containing not more than two sentences of plain text (disregarding bibliography), and only as long as the author doesn't offer anything that could be considered original research.

In 2015, Wikidata started incorporating the RE project by creating basic items for the articles and cross-references present on Wikisource. In turn, the RE project on Wikisource started featuring links to Wikidata items in 2017.

Showcase items and examples

Items for RE articles

Items for RE articles should have a label at least in English and German, consisting of the headword and (Pauly-Wissowa) in round brackets. They should also have the following statements:

... TBC

How to link articles to subject

RE article itemmain subject (P921)subject item
subject itemdescribed by source (P1343)Pauly–Wissowa (Q1138524) with qualifier statement is subject of (P805)RE article item

#title:All the links between RE articles and topic
SELECT ?article ?articlelabel ?topic ?topiclabel
WHERE {
  ?article wdt:P31 wd:Q13433827 ; wdt:P361 wd:Q1138524 ; rdfs:label ?articlelabel ; wdt:P921 ?topic . FILTER(LANG(?articlelabel) = "de")
  OPTIONAL { ?topic rdfs:label ?topiclabel . FILTER(LANG(?topiclabel) = "de") } .
}

All the links between RE articles and topic

Showcase queries

Number of times an RE article is used as reference

SELECT (count(?ref) as ?mentions) WHERE {
  ?statement prov:wasDerivedFrom ?ref .
  ?ref pr:P248 ?REArticle .
  ?REArticle wdt:P361 wd:Q1138524 .
}

Try it!

Most used RE articles for references by count

SELECT DISTINCT ?REArticle ?REArticleLabel (count(?REArticle) as ?mentions) WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?statement prov:wasDerivedFrom ?ref .
  ?ref pr:P248 ?REArticle .
  ?REArticle wdt:P361 wd:Q1138524 .
}

GROUP BY ?REArticle ?REArticleLabel
ORDER BY DESC(?mentions)

Try it!

Most used RE articles for references across multiple items

SELECT ?REArticle ?REArticleLabel (COUNT(DISTINCT ?item) as ?mentions)
WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?item ?property ?statement .
  ?statement prov:wasDerivedFrom ?ref .
  ?ref pr:P248 ?REArticle .
  ?REArticle wdt:P361 wd:Q1138524 .
}
GROUP BY ?REArticle ?REArticleLabel
ORDER BY DESC(?mentions)

Try it!

Items not present in RE

SELECT ?item ?itemLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?item wdt:P9660 wd:Q1138524 .
}

Try it!

Maintenance queries

Articles without main subject (P921)

SELECT ?article ?articlelabel
WHERE {
  ?article wdt:P31 wd:Q13433827 ; wdt:P361 wd:Q1138524 ; rdfs:label ?articlelabel . FILTER(LANG(?articlelabel) = "de")
  MINUS { ?article wdt:P921 ?topic } .
}
ORDER BY ASC(?articlelabel)

Try it!

#title:Longest RE articles (10+ columns) without specified topic
SELECT ?article ?articlelabel ?cols ?nc
WHERE {
  ?article wdt:P31 wd:Q13433827 ; wdt:P361 wd:Q1138524 ; rdfs:label ?articlelabel ; wdt:P3903 ?cols . FILTER(LANG(?articlelabel) = "de")
  BIND(REPLACE(?cols, "(\\d*)–(\\d*)", "$1") AS ?first)
  BIND(REPLACE(?cols, "(\\d*)–(\\d*)", "$2") AS ?last)
  BIND(xsd:integer(?last) - xsd:integer(?first) AS ?nc) FILTER(?nc > 9)
  MINUS { ?article wdt:P921 ?topic } .
}
ORDER BY DESC(?nc) ASC(?articlelabel)

Longest RE articles (10+ columns) without specified topic

Items described by RE without a proper link to the article

SELECT ?item ?itemLabel ?REArticle WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?item p:P1343 [ ps:P1343 wd:Q1138524 ;
                  pq:P958 ?REArticle ].
}
ORDER BY ?REArticle

Try it!

Items described by RE without a proper link to the article and the article exists

#There should be no results for this query
PREFIX wd: 
PREFIX wdt: 
PREFIX p: 
PREFIX ps: 
PREFIX pq: 
SELECT ?REarticle ?REtitle ?wikidata WHERE {
  ?REarticle wdt:P31 wd:Q13433827 ;
        wdt:P361 wd:Q1138524 ;
        wdt:P1476 ?title .
  BIND(STR(?title) as ?REtitle)
  ?wikidata p:P1343 [ ps:P1343 wd:Q1138524 ;
                                  pq:P958 ?REtitle ] .

}
ORDER BY ?REtitle

Try it! (QLever)

Items described by RE without the reprocity on the article

SELECT ?REArticle ?REArticleLabel ?item ?itemLabel ?item2 ?item2Label WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?item p:P1343 [ps:P1343 wd:Q1138524 ;
                 pq:P805 ?REArticle ].
  MINUS {?REArticle p:P921 [ps:P921 ?item ;
                            wikibase:rank ?anyRank ] }
  ?REArticle wdt:P921 ?item2 .
  }

Try it!

SELECT ?REArticle ?REArticleLabel ?item ?itemLabel ?itemDescription WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?item p:P1343 [ps:P1343 wd:Q1138524 ;
                 pq:P805 ?REArticle ].
  MINUS {?REArticle p:P921 [ps:P921 ?item ;
                            wikibase:rank ?anyRank ] }
  MINUS { ?REArticle wdt:P921 ?item2 } .
  }

Try it!

Items described by RE in a wrong format

#There should be no results for this query
SELECT ?item ?itemLabel ?REArticle WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?item wdt:P1343 ?REArticle .
  ?REArticle wdt:P361 wd:Q1138524 .
}

Try it!

Participants

[+] Add yourself to the list

The participants listed below can be notified using the following template in discussions:
{{Ping project|Antiquity}}